Overview of HP Workforce Experience Query Language

HP Workforce Experience Query Language (HP WXPQL) is powerful, user-friendly custom query language designed to streamline data retrieval and analysis of insights data of the Workforce Experience Platform. This query language abstracts the underlying databases to enable users to access data quickly and easily without requiring individual entity-level API support from HP Workforce Experience Platform.

The purpose of this documentation is to provide a comprehensive guide to effectively query, retrieve, and analyze data. It explains the structure of queries, the fields and their properties (such as data type, format, and mandatory status), and offers practical examples for implementation.

The tables in HP WXPQL can be categorized as one of three kinds.

Type 1: Tables with a single record per device, such as Device and BIOS.
Type 2: Tables with multiple records per device, such as Software Inventory and Software Updates.
Type 3: Event-based tables with historical information, such as BSODs.

HP WXPQL Syntax

Syntax Summary

Multiple line

Tablename
| project column1, column2, column3
| filter
| sort by <column> <desc/asc>
| limit <#> skip <#>

or single line

Tablename | project column1, column2, column3 | filter | sort by <column> <desc/asc> | limit <#> skip <#>

Table Name (required)

The table name should be the first component in the query and is the only required keyword. All other keywords are optional. If only the table name is in the query, then a maximum of 500 records will be returned.

In addition, all tables have a set of default columns which can be found via calling the /table-metadata endpoint with that table name in the query. Only these default columns will all show up in the query response if no keywords are added to the query.

Project

project is an operator and refers to the selection of specific columns to be included in the query result.

Tablename | project <columnname1>, <columnname2>, ...

Note:
The term project is optional. If omitted, the system returns a default list of fields, which is a subset of all fields in the database.

Note:
A custom column name can be assigned to the column using the below format:
Tablename | project mycustomname = <columnname>

Filter

Note: Every field and filter is case sensitive. All device models used in queries will be in UPPER CASE. Operators are not case sensitive.

The "filter" keyword functions like the WHERE clause in SQL and it is used to filter results based on parameters.
The supported operators include:

Operator	Description
`eq`	Equal to
`neq`	Not equal to
`lt`	Less than
`le`	Less than or equal to
`gt`	Greater than
`ge`	Greater than or equal to
`like`	- Requires a minimum of three characters. - Latency is higher than `eq`; use `eq` if an exact match is known. - Syntax: `Tablename \| filter deviceSn like "12345"`
`in`	- Matches multiple values. - Syntax: `Tablename \| filter deviceSn in ("12345", "ABCDE")`
`AND` `OR`	Logical operators are supported to connect multiple filters.

Example

BIOS
| project deviceSn, deviceName, installedBiosVersion, biosStatus, latestBiosVersion
| filter deviceModel like "ELITE"
| sort by deviceSn asc
| limit 500 skip 100

Limit and skip

The limit restricts the number of records, starting from the skip. If limit is not specified, a default of 500 rows is returned.

Syntax: | limit 10 skip 9. This example returns 10 records starting from the (9 +1)th record.

Example

BIOS
| project deviceSn, deviceName, installedBiosVersion, biosStatus, latestBiosVersion
| filter deviceModel like "ELITE"
| sort by deviceSn asc
| limit 500 skip 100

Sort By

The sort by keyword is used to sort the results based on ascending and descending order.
Syntax: tablename | sort by <field name> <asc/desc>

Distinct

The distinct keyword is used to get distinct values of a column or the distinct values in multiple columns.
Syntax:

tablename | distinct columnname1
tablename | distinct columnname1, columnname2, columnname3, ...

Note: The distinct and project operators cannot co-exist. That is, you will get an error if a query has both distinct and project.

Summarize

Use the summarize operator to aggregate and summarize data from the input table. There are six kinds of summarizations supported:

Summarization Type	Description
`count`	Counts the total number of records.
`countDistinct`	Counts the number of unique values.
`sum`	Calculates the total sum of a numeric column.
`avg`	Computes the average of a numeric column.
`min`	Finds the minimum value in a column.
`max`	Finds the maximum value in a column.

Syntax:

tablename | summarize [customname =] <summarize_function> (columnname) [by table_column_name1, table_column_name2, ...]

Count

Use the count keyword to count the number of records.
Syntax: tablename | summarize count(columnname) by columname1, columname2

Example:
This example gives the count of blue screen errors by bug check code and by device model.

BlueScreenErrors | summarize count(bugCheckCode) by bugCheckCode, deviceModel

Count Distinct

Use the countDistinct keyword to count the number of records with distinct values in that column.
Syntax: tablename | summarize countDistinct(columnname) by columname1, columname2

Example:
This example gives the count of distinct devices grouped by BIOS status.

BIOS | summarize countDistinct(deviceSn) by biosStatus

Sum

Use the sum keyword to add the values of a column. Sum can be applied only on integer, float, and double columns.
Syntax: tablename | summarize sum(columname) by columname1, columname2

Example:
This example gives the sum of app usage hours for Zoom by the device with serial number 12345.

DeviceSoftwareUtilization
| summarize sum(appUsageHrs)
| filter deviceSn eq "12345" and appName eq "Zoom"

Average

Use the avg keyword to average the values of a column. Average can be applied only on integer, float, and double columns.
Syntax: tablename | summarize average(columname) by columname1, columname2

Example:
This example gives the average of hours the CPU has been overutilized by device model.

DeviceUtilization | summarize avg(cpuOverUtilHrs) by deviceModel

Min

Use the min keyword to get the minimum value of a column.
Syntax: tablename | summarize min(columname)

Example:
This example gives the minimum disk size in MB of all devices by operating system.

DiskHealth | summarize min(sizeOriginal) by deviceOS

Max

Use the max keyword to get the maximum value of a column.
Syntax: tablename | summarize max(columname)

Example:
This example gives the max device age per device with device model to help find Windows 11 compatibility.

Windows11Compatibility
| summarize max(deviceAge) by deviceModel
| sort by max(deviceAge) asc

Table Overview

Table Name	Name	Description
`BIOS`	BIOS	This table provides detailed BIOS information of devices enrolled in WXP. The status of whether the BIOS is outdated or not is present only for HP devices.
`BIOSSettings`	BIOS Settings	This table provides details about the BIOS settings of the device. Each record represents a unique BIOS setting for a device.
`BatteryHealth`	Battery Health	This table provides the battery status for HP devices.
`BlueScreenErrors`	Blue Screen Errors	This table provides details of blue screen errors on devices. Each record corresponds to one crash and data exists for the past 4 months.
`BootPerformance`	Boot Performance	This table shows the On/Off performance of the devices by time segment, as well as the main slowdown reasons and the time since last restart.
`ChromeAUE`	Chrome AUE	This table provides information on the when the device will no longer receive automatic software updates from Google.
`DataHealth`	Data Health	This table provides details about the health of different kinds of data associated with a device. This does not include details related to any health of the device.
`DeploymentStatus`	Deployment Status	This table provides details about the deployment ring policy as well as the proxy on the device. Each record represents either deployment policy data or proxy info for a device. For the records corresponding to deployment policy, `deploymentPolicy` column ≠ NA and for records corresponding to proxy, `proxyPolicy` column ≠ NA.
`DeviceDEXScore`	Device DEX Score	The DEX score is a single, easy-to-interpret number designed to measure the overall digital experience of your employees. This table will contain device scores for System Health, OS Performance, Security, Application and Network categories. This table will have two records per device identified by latestFlag 'Y' for latest day and 'N' for last week. When querying this data, only 50 columns will be returned by default. In the query construction also, when adding a "project" keyword, only 50 columns can be specified.
`DeviceSecurityCompliance`	Device Security Compliance	This table can be used to get both the 24-hour and monthly device security compliance data. Use the filter `month eq "Today"` for 24-hour data and `month neq "Today"` for monthly data.
`DeviceSoftwareUtilization`	Device Software Utilization	This table provides the utilization info of desktop applications at a device level per month for 6 months.
`DeviceUtilization`	Device Utilization	Detailed information of CPU, memory, and software performance of enrolled devices for the current month.
`DiskHealth`	Disk Health	This table provides details about the disk health and issues.
`DisplayInventory`	Display Inventory	details about the display monitors associated with devices.
`DriverInventory`	Driver Inventory	This table contains all PnP drivers that are detected on a device. Each record corresponds to one driver instance and it gives detailed information regarding the driver like installed version, inf file, driver release date, etc.
`GPUPerformance`	GPU Health and Performance	This table provides information about the GPU Health/Performance.
`HardwareWarranty`	Hardware Warranty	details of warranty and care pack status of devices enrolled in proactive management.
`MissingSoftPaqDeviceDetails`	Missing SoftPaq Device Details	This table contains information about missing SoftPaq installations on a device.
`NetworkAssessment`	Network Assessment	This table provides network information for a device such as the Wi-Fi strength, nominal speed, network driver status, etc. By default, it returns one record per device per network. Use the filter `(latestPerNetworkFlg eq "N" OR latestPerNetworkFlg eq "Y")` to retrieve the past 7 days of data.
`NetworkDisconnections`	Network Disconnections	This table provides the details of network disconnections on devices for the last 90 days. Each record represents one disconnection on a device.
`NetworkInventory`	Network Inventory	This table provides comprehensive information about the network configuration and connectivity status of enrolled devices. It enables clients to retrieve details such as IP addresses, MAC addresses, connection ID, network names, and other relevant metadata associated with each device on the network.
`NonReportingDevices`	Non Reporting Devices	This table provides data about the last activity time of devices. This gives 24-hour delayed data.
`SoftPaqRecommendationStatusHistory`	SoftPaq Recommendation Status History	This table contains information about the recommended SoftPaqs and their installation status on the devices.
`SoftwareUtilizationSummary`	Software Utilization Summary	This table provides information about the utilization of software applications in the entire fleet. This has one record per application per app version per OS per month. This has data for the past 6 months (including the current month).
`SureStart`	HP Sure Start	This table provides details about the HP Sure Start events for a device.
`Sustainability`	Sustainability	This table holds the power consumption informaiton of PCs. This has the power consumption per week for a device. Each record corresponds to a week. Power consumption data is available only for devices with PCM or EC power measurement capabilities.
`Windows11Compatibility`	Windows 11 Compatibility	This table provides information related to the Windows 11 compatibility of devices.
`WindowsDefenderThreatDetails`	Windows Defender Threat Details	This table provides details of the threats which occurred on the devices. Each record corresponds to a threat on a device.
`WindowsUpdateDetails`	Microsoft Windows Update Details	This table provides details about the missing Windows updates on the devices. This has one record per missing update per device.
`WindowsUpdates`	Microsoft Windows Updates	This table provides aggregated details of missing Windows updates (count of missing updates per update category) on a device.

Query Examples

BIOS

Example:
API request to retrieve the list of all device names, model, installed BIOS version and serial number where device model is “HP ELITEBOOK 860 16 INCH G11 NOTEBOOK PC", sorted by device serial number, and limiting rows to 10.

BIOS
| project deviceName,deviceModel,deviceSn
| filter deviceModel eq "HP ELITEBOOK 860 16 INCH G11 NOTEBOOK PC"
| sort deviceSn asc
| limit 10

Example:
API request to summarize all device BIOS status in the fleet by device model, sorted by number of devices per status and model.

BIOS
| summarize deviceCount = countDistinct(deviceSn) by deviceModel,biosStatus
| sort countDistinct(deviceSn) desc, deviceModel desc

BIOS Settings

Example
API request to retrieve and sort BIOS configuration details for all devices, showing key hardware, OS, and user information to support inventory, compliance, or troubleshooting efforts.

BIOSSettings
| project deviceSn,deviceName,deviceModel,installedBiosVersion,biosSetting,biosSettingValue,lastSignedInUser
| sort deviceSn asc,biosSetting asc

Battery Health

Example:
API request to retrieve the Battery Health details of all devices in the fleet, where bhmsetting equals “Let HP manage my battery charging” and sorted by bhmSetting and deviceName values.

BatteryHealth
| project finalSwellReplace,deviceName,deviceModel,mfgYear,warrantyStatus,bhmSetting,batteryHealthManager
| sort bhmSetting asc, deviceName asc
| filter bhmSetting eq "Let HP manage my battery charging"
| limit 25 skip 0

Example:
API request to summarize distinct battery health manager settings, sorted by total devices per setting.

BatteryHealth
| summarize deviceCount = countDistinct(deviceSn) by bhmSetting
| sort by countDistinct(deviceSn) desc

Blue Screen Errors

Example:
API request to retrieve Blue Screen error diagnostics—such as device ID, OS version, error codes, crash timestamps, and user context—sorted by device serial number and crash time to support root cause analysis and fleet stability monitoring.

BlueScreenErrors
| project deviceSn, deviceName, deviceOS, OSVersion, crashOccurrenceTime, bugCheckCode, bugCheckCodeDescription, lastSignedInUser
| sort deviceSn asc, crashOccurrenceTime desc

Boot Performance

Example:
API request to retrieve device boot performance metrics—such as total boot time, restart events, and weekly trends—alongside user and device metadata, sorted by serial number for performance monitoring and optimization.

BootPerformance
| project deviceSn, deviceName, deviceModel, deviceOSOriginal, OSVersion, lastRestartDate, totalTime, currentWeekMPBT, currentWeekBPBT, reasonList, lastSignedInUser
| sort deviceSn asc

Chrome AUE

Example:
API request to retrieve and sort Chrome device auto-update expiration details—along with key device and location metadata—to help track upcoming support deadlines and prioritize device lifecycle actions.

ChromeAUE
| project deviceId, autoUpdateExpiration, expirationDate, deviceName, deviceSn, deviceModel
| sort autoUpdateExpiration desc, expirationDate desc, deviceSn asc

Data Health

Example:
API request to retrieve device health and utilization metrics—such as OS, thermal, driver, battery, and disk health, sorted by device serial number for streamlined diagnostics and fleet monitoring.

DataHealth
| project deviceSn,deviceOS,OSDataHealth,thermalDataHealth,driverDataHealth,deviceUtilizationDataHealth,softwareUtilizationDataHealth,softwarePerformanceDataHealth,batteryDataHealth,diskDataHealth,diskDataHealthDetails
| sort deviceSn asc

Deployment Status

Example:
API request to retrieve deployment status details for devices—such as enrollment date, last seen time, installed package versions, and policy compliance—sorted by device name and package name to support monitoring and troubleshooting.

DeploymentStatus
| project deviceSn,deviceName,deviceOS,dateEnrolled,lastSeen,packageName,deploymentPolicy,installedVersion,policyHonored,proxyPolicy,proxyDetails,finalPolicyErrorCode,errMsg
| sort deviceName asc, packageName asc

Device DEX Score

Example:
API request to retrieve the fleet’s Digital Experience (DEX) score—along with sub-scores and key performance indicators like performance, battery, network, and security—providing a comprehensive view of end-user experience across devices to support proactive IT operations and experience optimization.

DeviceDEXScore
| project deviceSn, deviceName, deviceModel, deviceOS, OSVersion, lastSignedInUser, performanceScore, batteryScore, networkScore, securityScore, appScore, bsodScore, startupTimeScore, shutdownTimeScore
| sort deviceModel asc

Device Security Compliance

Example:
API request to retrieve a 24-hour summary of company-wide security compliance metrics—such as compliance type, status, and time spent—filtered for the current month and sorted to highlight recent and non-compliant entries.

CompanySecurityCompliance
| project dateListMonth,complianceType,complianceStatus,deviceCount,hoursTotal,hoursSpent,hoursPercent
| filter month eq \"Today\"
| sort dateListMonth asc, complianceStatus desc

Device Software Utilization

Example:
API request to retrieve the utilization of all software installed on devices in the fleet, sorted by sorted by devicename, application usage hours and month, for the last 3 months.

DeviceSoftwareUtilization
| project appName,appType,appUsageHrs,appUsagePercent,appVersion,deviceSn,deviceName,month,percentRange,deviceOS
| sort deviceName asc, month desc, appUsageHrs asc
| filter ( month gt "2025-01-01" )

Device Utilization

Example:
API request to retrieve the Memory and CPU utilization data of all devices in the fleet, sorted by devicename,month, CPUNormalhours, and memoryNormal hours

DeviceUtilization
| project deviceSn,deviceModel,cpuOverUtilHrs,memOverUtilHrs,dateListMonth
| sort cpuOverUtilHrs asc, memOverUtilHrs asc

Disk Health

Example:
API request to retrieve the detailed disk information of all HP devices in the fleet, including the disk type, disk model, along with disk health status sorted by disk replacement timeframe.

DiskHealth
| project diskReplacementTimeframe,diskReplacementIssue,deviceSn,deviceName,diskType,diskModel,sizeTotalF,sizeOriginal,warrantyStatus
| sort diskReplacementTimeframe ASC, deviceName ASC

Display Inventory

Example:
API request to retrieve the list of all devices with connected display(s) and their model and serial number, Sort by Device nameSN.

DisplayInventory
| project deviceName,deviceSn,deviceModel,displaySerialNumber,displayModelName
| sort deviceName asc

Driver Inventory

Example:
API request to retrieve the list of drivers on all HP Elitebook 850 G7 notebooks, sorted by device name.

DriverInventory
| filter deviceModel eq \"HP ELITEBOOK 850 G7 NOTEBOOK PC\"
| project deviceSn, deviceName, deviceModel, driverName, driverCategory, driverVersion
| sort deviceName asc"

GPU Health and Performance

Example:
API request to retrieve the GPU performance information of all Windows 10 devices, which are not smartphones in the fleet, sorted by GPU heath category.

GPUPerformance
| project deviceName,deviceSn,graphics,deviceHealthCategory,problemsDetected,suggestedSolutions
| filter deviceOS eq "Windows 10" and deviceType neq "Smartphone"
| sort deviceHealthCategory asc
| limit 10 skip 0

Hardware Warranty

Example:
API request to retrieve the hardware warranty information of devices in the fleet where the warranty of the device has not expired, sorted by fewest days remaining in warranty.

HardwareWarranty
| project warrantyDaysRemainingOverall,maxOblEndDate,deviceName,deviceSn,warrantyStatusOverall
| filter warrantyStatus neq "Out of warranty"
| sort warrantyStatusOverall asc, warrantyDaysRemainingOverall asc
| limit 10 skip 0

Example:
API request to get the count of all devices in each warranty status category: In warranty, Out of warranty, Unknown.

HardwareWarranty | summarize countDistinct(deviceSn) by warrantyStatus

Missing SoftPaq Device Details

Example:
API request to retrieve the top missing SoftPaqs across devices, including the number of impacted devices, version details, criticality, and associated download links.

MissingSoftPaqDeviceDetails | summarize  impactedDeviceCount = countDistinct(deviceSn) by softpaqID, softpaqTitle, softpaqVersion, vendorVersion, categoryName, criticality, releaseNotesURL,downloadURL,CVAURL | filter criticality in (\"Routine\",\"Recommended\",\"Critical\")  | limit 25 skip 0 | sort countDistinct(deviceSn) desc

Network Assessment

Example:
API request to retrieve network performance and connectivity diagnostics—such as connection type, VPN status, signal strength, and driver health—alongside device and user context, sorted by device serial number for fleet-wide network reliability analysis.

NetworkAssessment
| project deviceSn, deviceName, connectionType, isVPNConnected, signalStrength, networkType, networkName, latestDriverCriticality, driverStatus, lastSignedInUser
| sort deviceSn asc

Network Disconnections

Example:
API request to retrieve network disconnection events—capturing connection type, network details, driver status, and user context—sorted by device serial number to support root cause analysis and connectivity reliability tracking.

NetworkDisconnections
| project deviceSn, deviceName, connectionType, networkType, networkName, networkCardName, latestDriverCriticality, driverStatus, lastSignedInUser, dateTime
| sort deviceSn asc

Network Inventory

Example:
API request to retrieve detailed network adapter inventory—covering adapter type, connection ID, encryption, and driver criticality—alongside device and user metadata, sorted by device serial number for hardware and connectivity audits.

NetworkInventory
| project deviceSn, deviceName, adapterType, networkConnectionId, ssid, securityType, networkEncryption, latestDriverCriticality, lastSignedInUser
| sort deviceSn asc

Non Reporting Devices

Example:
API request to retrieve the list of non-reporting HP devices in the fleet sorted by last seen.

NonReportingDevices
| project lastSeen, deviceName, deviceSn, deviceType, deviceMfg, lastSeenWeeksAgo, dateEnrolled, mfgDate
| filter deviceMfg eq "HP"
| sort lastSeen asc
| limit 10 skip 0

SoftPaq Recommendation Status History

Example:
[coming soon]

SoftPaqRecommendationStatusHistory

Software Utilization Summary

Example:
API request to retrieve software usage metrics—such as app usage hours, frequency, and version—across devices and orgs, sorted by usage percentage to identify high-value or underutilized applications.

SoftwareUtilizationSummary
| project appName, appUsageHrs, appUsageCount, appUsagePercent, appAvgUsageTime, appVersion, deviceCount, deviceOS
| sort appUsagePercent desc

HP Sure Start

Example:
API request to retrieve Sure Start firmware protection status—capturing device identity, OS, and user context—sorted by event type to support firmware integrity monitoring and security compliance.

SureStart
| project deviceSn, deviceName, deviceOS, lastSignedInUser, lastSeen, source, eventId, eventType, eventDesc
| sort eventType asc

Sustainability

Example:
API request to retrieve device-level sustainability metrics—such as power consumption, hardware specs, and warranty status—alongside user context, sorted by power consumption to support energy efficiency tracking and reporting.

Sustainability
| project deviceSn, deviceName, deviceModel, deviceOS, OSVersion, powerConsumption, powerMeasurementType, warrantyStatus, lastSignedInUser, countryCode
| sort powerConsumption asc

Windows 11 Compatibility

Example:
API request to retrieve the Windows 11 Compatibility status of all devices in the fleet, that isn't already running Windows 11 and sorted by the same status.

Windows11Compatibility
| project deviceSn,win11CompatibilityStatus,recommendation,warrantyStatus,warrantyEndDate,devicePerformanceRating,performanceMetrics,performanceDetails
| filter win11CompatibilityStatus neq "Running Windows 11"
| sort win11CompatibilityStatus asc

Windows11Compatibility | summarize countDistinct(deviceSn) by win11CompatibilityStatus)

Windows Defender Threat Details

Example:
API request to retrieve Windows Defender threat detection data—such as threat name, severity, detection source, and remediation action—alongside device and user context, sorted by detection time for security incident tracking and response.

WindowsDefenderThreatDetails
| project deviceSn, deviceName, deviceOS, dateTime, threatName, severity, detectionSource, action, errorDescription, lastSignedInUser
| sort dateTime desc

Microsoft Windows Update Details

Example:
API request to retrieve Windows update deployment details—such as update name, type, severity, and status—alongside device, OS, and user context, sorted by update status and device name to support patch compliance and troubleshooting.

WindowsUpdateDetails
| project deviceName, deviceSn, deviceOS, OSRelease, lastSeen, updateName, updateType, updateSeverity, updateStatus, kbCode, lastSignedInUser
| sort updateStatus desc, deviceName asc

Microsoft Windows Updates

Example:
API request to retrieve the list of devices in the fleet with missing Windows update, sorted by count of missing updates and devicename.

WindowsUpdates
| project deviceSn,,missingUpdatesCount,updateClassification,deviceOS,OSRelease
| sort missingUpdatesCount desc, deviceName asc